collapse

* Posts Recentes

Amplificador - Rockboard HA 1 In-Ear por almamater
[27 de Março de 2024, 19:13]


O que é isto ? por KammutierSpule
[26 de Março de 2024, 19:35]


Bateria - Portátil por almamater
[25 de Março de 2024, 22:14]


Emulador NES em ESP32 por dropes
[13 de Março de 2024, 21:19]


Escolher Osciloscópio por jm_araujo
[06 de Fevereiro de 2024, 23:07]


TP4056 - Dúvida por dropes
[31 de Janeiro de 2024, 14:13]


Leitura de dados por Porta Serie por jm_araujo
[22 de Janeiro de 2024, 14:00]


Distancia Cabo por jm_araujo
[08 de Janeiro de 2024, 16:30]


Meu novo robô por josecarlos
[06 de Janeiro de 2024, 16:46]


Laser Engraver - Alguém tem? por almamater
[16 de Dezembro de 2023, 14:23]

Autor Tópico: SMPS Boost - Fonte comutada elevadora de tensão  (Lida 4860 vezes)

0 Membros e 1 Visitante estão a ver este tópico.

Offline Sérgio_Sena

  • Administrator
  • Mini Robot
  • *****
  • Mensagens: 1.649
    • Electronic Gear for Musicians
SMPS Boost - Fonte comutada elevadora de tensão
« em: 06 de Março de 2011, 00:15 »
Wild electronics  ;D a funcionar. Descobri esta relíquia no fundo da caixa de ferramentas. Bem usada nas corridas de carrinhos fotovoltaicos!



Input de 8 a 24V, Output sempre de 24V
Boa resposta até 1A.
Sem testes de comportamento THD e eficiência. Funcionou para o que se queria, usou-se e arrumou-se.


Projecto está aqui ::
http://www.antoniosergiosena.com/electronica.htm

Mas para quem quiser ver num instante o esquema ::



Código fonte não limpo, arranjado ou optimizado ::
Código: [Seleccione]
;-------------------------------------------------------------------------
;
; Controlador de Energia para Carrinhos Solares
;
; 037, v0.1, 16F628A
;
; A. Sergio Sena, [url=http://www.antoniosergiosena.com]www.antoniosergiosena.com[/url], Tel.: 967.033.209
;-------------------------------------------------------------------------

list p=16f628A ;configura o tipo de CPU usado
radix hex ;pre-definicao do tipo de valores numericos usados

include "p16f628a.inc" ;

__config _CP_OFF & _DATA_CP_OFF & _LVP_OFF & _BOREN_OFF & _MCLRE_ON & _INTOSC_OSC_NOCLKOUT & _PWRTE_ON & _WDT_OFF


;---------------------------

temp equ 0x20 ;define endereco 0x20 com o nome de TEMP
temp2 equ 0x21 ;define endereco 0x21 com o nome de TEMP2
temp3 equ 0x22 ;define endereco 0x21 com o nome de TEMP3

;---------------------------



org 0x0000 ;vector de RESET
goto inicio



org 0x0020
inicio

banksel PORTA
clrf PORTA ;limpa tristates da porta A
clrf PORTB ;limpa tristates da porta B

;configura pinos RA1 e RA2 como entradas analogicas
banksel CMCON
movlw 0x05
movwf CMCON ;move de W para CMCON


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;configura portas A e B como entradas/saidas
banksel TRISA

movlw b'00000110'
movwf TRISA
clrf TRISB ;TRISB toda como saida

movlw 0x12 ;periodo do PWM (faz 52kHz com as configurações do TMR2)
movwf PR2

movlw b'11101100' ;Tensao de Referencia
movwf VRCON

banksel PORTA
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

movf CMCON, f ;remove indecisão de leitura


;configura modulo CCP para trabalhar em PWM
movlw 0x0F
movwf CCP1CON
;liga TMR2 e pré-divisor de 1:1
movlw 0x04
movwf T2CON


;duty-cycle do PWM (periodo activo)
movlw .1
movwf CCPR1L

call atraso_2s

;---------------------------------------------------------------------------
volta
call atraso_20m ;espera um pouco

btfss CMCON, 7 ;verifica se ampop2 tem saida activa
goto desce


sobe
incf CCPR1L, f ;aumenta uma unidade
movlw .12 ;se tiver passado o máximo, mantém sempre no máximo
subwf CCPR1L, w
btfss STATUS, Z
goto fim_sobe
movlw .11 ;carrega com o máximo
movwf CCPR1L
fim_sobe
goto volta


desce
decfsz CCPR1L, f ;diminui uma unidade
goto fim_desce
movlw .1 ;carrega com o minimo
movwf CCPR1L
fim_desce
goto volta ;ciclo infinito


;---------------------------------------------------------------------------


atraso_2s
movlw .100
movwf temp3 ;move valor em W para TEMP

call atraso_20m ;

decfsz temp3, f ;decrementa TEMP em uma unidade, coloca resultado em TEMP
;e salta a instrucao seguinte, se o resultado for zero
goto $-2 ; salta para duas instrucoes anteriores

return ;sai fora da rotina de ATRASO

;---------------------------

atraso_20m
movlw .40
movwf temp2 ;move valor em W para TEMP

call atraso_500u ;

decfsz temp2, f ;decrementa TEMP em uma unidade, coloca resultado em TEMP
;e salta a instrucao seguinte, se o resultado for zero
goto $-2 ; salta para duas instrucoes anteriores

return ;sai fora da rotina de ATRASO

;---------------------------

atraso_500u
movlw 0xA5
movwf temp ;move valor em W para TEMP

decfsz temp, f ;decrementa TEMP em uma unidade, coloca resultado em TEMP
;e salta a instrucao seguinte, se o resultado for zero
goto $-1 ;salta para uma instrucao anterior

return ;sai fora da rotina de ATRASO

;---------------------------


end

Offline andre_f_carvalho

  • Mini Robot
  • *
  • Mensagens: 1.469
    • Pro - andrefcarvalho
Re: SMPS Boost - Fonte comutada elevadora de tensão
« Responder #1 em: 06 de Março de 2011, 23:43 »
para que serve o pic ou o picaxe neste esquema?

Offline metRo_

  • Administrator
  • Mini Robot
  • *****
  • Mensagens: 3.753
Re: SMPS Boost - Fonte comutada elevadora de tensão
« Responder #2 em: 06 de Março de 2011, 23:45 »
Para controlar o IRF530

Offline ivitro

  • Mini Robot
  • *
  • Mensagens: 451
Re: SMPS Boost - Fonte comutada elevadora de tensão
« Responder #3 em: 07 de Março de 2011, 01:44 »
para estar a comutar o mosfet e controlar o motor.


Offline senso

  • Global Moderator
  • Mini Robot
  • *****
  • Mensagens: 9.733
  • Helpdesk do sitio
Re: SMPS Boost - Fonte comutada elevadora de tensão
« Responder #4 em: 08 de Março de 2011, 18:57 »
Não tem nenhum motor, pelo menos não directamente acho eu, o que o PIC está a fazer é a controlar a modulação PWM do mosfet para alterar a voltagem de saida consoante a de entrada, para a manter constante.
É um conversor de voltagem do tipo boost, ou seja, aumenta a tensão de entrada para um valor constante á saida, que é maior ou igual que a tensão na entrada.
Avr fanboy

Offline ivitro

  • Mini Robot
  • *
  • Mensagens: 451
Re: SMPS Boost - Fonte comutada elevadora de tensão
« Responder #5 em: 02 de Abril de 2011, 01:53 »
Como se chega a relação do pwm com a saida?

exemplo: quanto tempo on tem que estar o mosfet on para ter 1A a saida

Offline senso

  • Global Moderator
  • Mini Robot
  • *****
  • Mensagens: 9.733
  • Helpdesk do sitio
Re: SMPS Boost - Fonte comutada elevadora de tensão
« Responder #6 em: 02 de Abril de 2011, 04:53 »
A voltagem é que é regulada,e não a corrente, penso que a melhor maneira de o fazer é usar um divisor resistivo, e ler a voltagem á saida, enrola-se num PID e controla-se o duty-cycle do pwm para dar a voltagem estabelecida.
Avr fanboy