collapse

* Links de Robótica

* Posts Recentes

Recomendação de um opamp para um DAC r2r por jm_araujo
[Hoje às 10:48]


Feira de electricidade e eletrónica por beirao
[Hoje às 00:32]


RN42 e TP-Link MR3020 por doiga
[Ontem às 19:22]


Ajuda Projecto IR / RF por senso
[Ontem às 13:15]


Ideias para construir um quadrúpede simples por dropes
[21 de Novembro de 2017, 22:43]


Ajuda com TRIAC por senso
[17 de Novembro de 2017, 18:00]


TV LG White Screen por almamater
[15 de Novembro de 2017, 08:37]


Pergunta sobre prototipagem ( Pesquisa ) por luisjustin
[14 de Novembro de 2017, 23:22]


Medir Agua que está no Poço por Njay
[14 de Novembro de 2017, 13:28]


Amplificador audio por beirao
[12 de Novembro de 2017, 23:43]

Autor Tópico: WATERPROOF DS18B20 TEMPERATURE SENSOR  (Lida 1545 vezes)

0 Membros e 1 Visitante estão a ver este tópico.

Offline magtaem

  • Mini Robot
  • *
  • Mensagens: 25
WATERPROOF DS18B20 TEMPERATURE SENSOR
« em: 21 de Junho de 2014, 15:50 »
Boas pessoal tenho uma dúvida referente a este sensor, fiz a ligação deste sensor como mostra a seguinte imagem



VCC -5v
DATA - Pino 2
GND - GND

NO arduino coloquei o seguinte código:

Código: [Seleccione]
#include <OneWire.h>

int DS18S20_Pin = 2; //DS18S20 Signal pin on digital 2

//Temperature chip i/o
OneWire ds(DS18S20_Pin);  // on digital pin 2

void setup(void) {
  Serial.begin(9600);
}

void loop(void) {
  float temperature = getTemp();
  Serial.println(temperature);
 
  delay(100); //just here to slow down the output so it is easier to read
 
}


float getTemp(){
  //returns the temperature from one DS18S20 in DEG Celsius

  byte data[12];
  byte addr[8];

 // if ( !ds.search(addr)) {
      //no more sensors on chain, reset search
      // ds.reset_search();
     //  return -1000;
  // }

   //if ( OneWire::crc8( addr, 7) != addr[7]) {
     //  Serial.println("CRC is not valid!");
      // return -1000;
  // }

  // if ( addr[0] != 0x10 && addr[0] != 0x28) {
    //   Serial.print("Device is not recognized");
     //  return -1000;
  // }

  ds.reset();
  ds.select(addr);
  ds.write(0x44,1); // start conversion, with parasite power on at the end

  byte present = ds.reset();
  ds.select(addr);   
  ds.write(0xBE); // Read Scratchpad

 
  for (int i = 0; i < 9; i++) { // we need 9 bytes
    data[i] = ds.read();
  }
 
  ds.reset_search();
 
  byte MSB = data[1];
  byte LSB = data[0];

  float tempRead = ((MSB << 8) | LSB); //using two's compliment
  float TemperatureSum = tempRead / 16;
 
  return TemperatureSum;
 
}

Mas o sensor retorna sempre 0.00 , não dá valores, o que estou a fazer de mal?
 Nota : Já importei a library onewire


Cumprimentos
"O mundo pertence a quem se atreve"

Offline senso

  • Global Moderator
  • Mini Robot
  • *****
  • Mensagens: 9.402
  • Helpdesk do sitio
Re: WATERPROOF DS18B20 TEMPERATURE SENSOR
« Responder #1 em: 21 de Junho de 2014, 15:56 »
Começa por tirar os comentários da parte em que diz se está a identificar o sensor ou não.
Tens resistência de pull-up de 10k na linha de dados?
Avr fanboy

Offline magtaem

  • Mini Robot
  • *
  • Mensagens: 25
Re: WATERPROOF DS18B20 TEMPERATURE SENSOR
« Responder #2 em: 21 de Junho de 2014, 16:00 »
Começa por tirar os comentários da parte em que diz se está a identificar o sensor ou não.
Tens resistência de pull-up de 10k na linha de dados?

SIm tenho a resistência, e se tirar essa parte dos comentários, ele dá o valor -1.
Eu só tirei para testar uma pequena coisa
"O mundo pertence a quem se atreve"

Offline senso

  • Global Moderator
  • Mini Robot
  • *****
  • Mensagens: 9.402
  • Helpdesk do sitio
Re: WATERPROOF DS18B20 TEMPERATURE SENSOR
« Responder #3 em: 21 de Junho de 2014, 16:10 »
Tenta usar uma biblioteca já feita, porque estás ai a chamar um addr, e não estou a entender de onde é que esse endereço vem.
Aliás, provavelmente o problema é mesmo esse, primeiro tens de fazer um scan á linha one wire para saber quem é que lá está, guardar os endereços num array e só depois é que lês sensor a sensor, dando o endereço dele.
Avr fanboy

Offline magtaem

  • Mini Robot
  • *
  • Mensagens: 25
Re: WATERPROOF DS18B20 TEMPERATURE SENSOR
« Responder #4 em: 21 de Junho de 2014, 16:18 »
Ou seja, vou roubar o código a outro lado certo?

Desde já obrigado pela ajuda
"O mundo pertence a quem se atreve"

Offline magtaem

  • Mini Robot
  • *
  • Mensagens: 25
Re: WATERPROOF DS18B20 TEMPERATURE SENSOR
« Responder #5 em: 21 de Junho de 2014, 16:31 »
Código correcto :

Código: [Seleccione]
#include <OneWire.h>

// OneWire DS18S20, DS18B20, DS1822 Temperature Example
//
// http://www.pjrc.com/teensy/td_libs_OneWire.html
//
// The DallasTemperature library can do all this work for you!
// http://milesburton.com/Dallas_Temperature_Control_Library

OneWire  ds(2);  // on pin 10 (a 4.7K resistor is necessary)

void setup(void) {
  Serial.begin(9600);
}

void loop(void) {
  byte i;
  byte present = 0;
  byte type_s;
  byte data[12];
  byte addr[8];
  float celsius, fahrenheit;

  if ( !ds.search(addr)) {
    Serial.println("No more addresses.");
    Serial.println();
    ds.reset_search();
    delay(250);
    return;
  }

  Serial.print("ROM =");
  for( i = 0; i < 8; i++) {
    Serial.write(' ');
    Serial.print(addr[i], HEX);
  }

  if (OneWire::crc8(addr, 7) != addr[7]) {
      Serial.println("CRC is not valid!");
      return;
  }
  Serial.println();

  // the first ROM byte indicates which chip
  switch (addr[0]) {
    case 0x10:
      Serial.println("  Chip = DS18S20");  // or old DS1820
      type_s = 1;
      break;
    case 0x28:
      Serial.println("  Chip = DS18B20");
      type_s = 0;
      break;
    case 0x22:
      Serial.println("  Chip = DS1822");
      type_s = 0;
      break;
    default:
      Serial.println("Device is not a DS18x20 family device.");
      return;
  }

  ds.reset();
  ds.select(addr);
  ds.write(0x44);        // start conversion, use ds.write(0x44,1) with parasite power on at the end

  delay(1000);     // maybe 750ms is enough, maybe not
  // we might do a ds.depower() here, but the reset will take care of it.

  present = ds.reset();
  ds.select(addr);   
  ds.write(0xBE);         // Read Scratchpad

  Serial.print("  Data = ");
  Serial.print(present, HEX);
  Serial.print(" ");
  for ( i = 0; i < 9; i++) {           // we need 9 bytes
    data[i] = ds.read();
    Serial.print(data[i], HEX);
    Serial.print(" ");
  }
  Serial.print(" CRC=");
  Serial.print(OneWire::crc8(data, 8), HEX);
  Serial.println();

  // Convert the data to actual temperature
  // because the result is a 16 bit signed integer, it should
  // be stored to an "int16_t" type, which is always 16 bits
  // even when compiled on a 32 bit processor.
  int16_t raw = (data[1] << 8) | data[0];
  if (type_s) {
    raw = raw << 3; // 9 bit resolution default
    if (data[7] == 0x10) {
      // "count remain" gives full 12 bit resolution
      raw = (raw & 0xFFF0) + 12 - data[6];
    }
  } else {
    byte cfg = (data[4] & 0x60);
    // at lower res, the low bits are undefined, so let's zero them
    if (cfg == 0x00) raw = raw & ~7;  // 9 bit resolution, 93.75 ms
    else if (cfg == 0x20) raw = raw & ~3; // 10 bit res, 187.5 ms
    else if (cfg == 0x40) raw = raw & ~1; // 11 bit res, 375 ms
    //// default is 12 bit resolution, 750 ms conversion time
  }
  celsius = (float)raw / 16.0;
  fahrenheit = celsius * 1.8 + 32.0;
  Serial.print("  Temperature = ");
  Serial.print(celsius);
  Serial.print(" Celsius, ");
  Serial.print(fahrenheit);
  Serial.println(" Fahrenheit");
}

Cumprimentos e obrigado
"O mundo pertence a quem se atreve"